IVZControlStyle.Background

Синтаксис Fore

Background: IGxBrush;

Синтаксис Fore.NET

Background: Prognoz.Platform.Interop.Drawing.IGxBrush;

Описание

Свойство Background определяет кисть, устанавливающую фон элемента управления.

Пример Fore

Для выполнения примера предполагается наличие в репозитории экспресс-отчета с идентификатором «EXP». Модуль, в котором размещается пример, должен иметь ссылки на системные сборки Express, Metabase, Drawing и Visualizators. Указанная процедура должна вызываться из точки входа Main.

До выполнения примера временная шкала пузырькового дерева выглядит так, как показано на странице описания интерфейса IVZBubbleTree. Установим новые значения для следующих свойств данной шкалы: фон, граница, шрифт, цвет шрифта, отступы, поля и цвет теней:

Sub UserProc;
Var
    Metabase: IMetabase; // Метабаза
    EaxAnalyzer: IEaxAnalyzer; // Экспресс-отчёт
    BubbleTree: IVZBubbleTree; // Пузырьковое дерево
    Timeline: IVZTimeLine; // Временная шкала
    Style: IVZControlStyle; // Стиль
Begin
    // Получим объект метабазы
    Metabase := MetabaseClass.Active;
    // Получим объект экспресс-отчёта
    EaxAnalyzer := Metabase.ItemById("EXP").Edit As IEaxAnalyzer;
    // Получим пузырьковое дерево
    BubbleTree := EaxAnalyzer.BubbleTree.BubbleTree;
    // Получим временную шкалу
    Timeline := BubbleTree.TimeLine;
    // Получим стиль временной шкалы
    Style := Timeline.Style;
    // Установим новый фон
    Style.Background := New GxSolidBrush.Create(New GxColor.CreateRGB(171, 205, 239));
    // Установим новый цвет границы
    Style.BorderPen := New GxPen.CreateSolid(New GxColor.CreateRGB(0, 0, 255), 3);
    
    
    // Установим новый шрифт
    Style.Font := New GxFont.Create("Tahoma", 15);
    // Установим новый цвет шрифта
    Style.FontColor := New GxColor.CreateRGB(0, 0, 0);
    // Установим отступы элемента
    Style.Margin := New GxRectF.Create(15, 15, 15, 15);
    // Установим поля элемента
    Style.Padding := New GxRectF.Create(10, 10, 10, 10);
    // Установим цвет теней
    Style.ShadowColor := New GxColor.CreateRGB(255, 0, 0);
    // Установим измененный стиль
    Timeline.Style := Style;
    // Установим измененную временную шкалу
    BubbleTree.TimeLine := Timeline;
    // Сохраним экспресс-отчет
    (EaxAnalyzer As IMetabaseObject).Save;
End Sub UserProc;

В результате выполнения примера были изменены следующие свойства временной шкалы пузырькового дерева: фон, граница, шрифт, цвет шрифта, отступы, поля и цвет теней:

Пример Fore.NET

Для выполнения примера предполагается наличие в репозитории экспресс-отчета с идентификатором «EXP». Указанная процедура является точкой входа Main в модуле Program .NET-сборки. В данный модуль должны быть импортированы сборки Express, Metabase, Drawing и Visualizators из системной сборки Prognoz.Platform.Interop.

До выполнения примера временная шкала пузырькового дерева выглядит так, как показано на странице описания интерфейса IVZBubbleTree. Установим новые значения для следующих свойств данной шкалы: фон, граница, шрифт, цвет шрифта, отступы, поля и цвет теней:

Public Shared Sub Main(Params: StartParams);
Var
    Metabase: IMetabase; // Метабаза
    EaxAnalyzer: IEaxAnalyzer; // Экспресс-отчёт
    BubbleTree: IVZBubbleTree; // Пузырьковое дерево
    Timeline: IVZTimeLine; // Временная шкала
    Style: IVZControlStyle; // Стиль временной шкалы
    BackgroundBrush: GxSolidBrush; // Кисть фоновой заливки
    BackgroundColor: GxColor; // Цвет фона
    BorderPen: GxPen; // Стиль рамки
    BorderColor: GxColor; // Цвет рамки
    Font: GxFont; // Шрифт
    FontColor: GxColor; // Цвет шрифта
    Margin: GxRectF; // Отступы элемента
    Padding: GxRectF; // Поля элемента
    ShadowColor: GxColor; // Цвет теней
Begin
    // Получим объект метабазы
    Metabase := Params.Metabase;
    // Получим объект экспресс-отчёта
    EaxAnalyzer := Metabase.ItemById["EXP"].Edit() As IEaxAnalyzer;
    // Получим пузырьковое дерево
    BubbleTree := EaxAnalyzer.BubbleTree.BubbleTree;
    // Получим временную шкалу
    Timeline := BubbleTree.TimeLine;
    // Получим стиль временной шкалы
    Style := Timeline.Style;
    // Установим новый фон
    BackgroundColor := New GxColor();
    BackgroundColor.CreateRGB(171, 205, 239);
    BackgroundBrush := New GxSolidBrush();
    BackgroundBrush.Create(BackgroundColor);
    Style.Background := BackgroundBrush;
    // Установим новый цвет границы
    BorderColor := New GxColor();
    BorderColor.CreateRGB(0, 0, 255);
    BorderPen := New GxPen();
    BorderPen.CreateSolid(BorderColor, 3);
    Style.BorderPen := BorderPen;
    
    
    // Установим новый шрифт
    Font := New GxFont();
    Font.Create("Tahoma", 15, GxFontStyle.gfsRegular, GxUnit.guInch);
    Style.Font := Font;
    // Установим новый цвет шрифта
    FontColor := New GxColor();
    FontColor.CreateRGB(0, 0, 0);
    Style.FontColor := FontColor;
    // Установим отступы элемента
    Margin := New GxRectF();
    Margin.Create(15, 15, 15, 15);
    Style.Margin := Margin;
    // Установим поля элемента
    Padding := New GxRectF();
    Padding.Create(10, 10, 10, 10);
    Style.Padding := Padding;
    // Установим цвет теней
    ShadowColor := New GxColor();
    ShadowColor.CreateRGB(255, 0, 0);
    Style.ShadowColor := ShadowColor;
    // Сохраним экспресс-отчет
    (EaxAnalyzer As IMetabaseObject).Save();
End Sub;

Результат выполнения примера аналогичен результату, полученному после выполнения примера для языка Fore.

См. также:

IVZControlStyle