IMetabaseSecurity.AddGroup

Синтаксис

AddGroup(GroupName: String): IMetabaseGroup;

Параметры

GroupName. Наименование группы пользователей.

Описание

Метод AddGroup создает новую группу пользователей.

Пример

Для выполнения примера добавьте ссылку на системную сборку Metabase.

Sub UserProc;
Var
    MB: IMetabase;
    MS: IMetabaseSecurity;
    Group: IMetabaseGroup;
    User: IMetabaseUser;
    Data: ISecurityPackageUserData;
    PS: IPasswordCredentials;
    Lic: Object;
Begin
    MB := MetabaseClass.Active;
    // Получим лицензию для возможности работы с менеджером безопасности
    Lic := MB.RequestLicense(UiLicenseFeatureType.Adm);
    MS := MB.Security;
    // Добавим группу пользователей и пользователя
    Group := MS.AddGroup("Тестовая группа");
    User := MS.AddUser("TestUser");
    User.FullName := "Тестовый пользователь";
    // Зададим привилегии пользователю
    MS.Policy.Privilege("ВХОД").Grant(User);
    MS.Policy.Privilege("ЧТЕНИЕ").Grant(User);
    // Зададим пароль пользователя
    Data := User.PackageData;
    PS := Data.Credentials As IPasswordCredentials;
    PS.Password := "Password";
    User.MustChangePasswordAtNextLogon := True;
    // Добавим пользователя в группу
    Group.AddMember(User);
    // Сохраним изменения
    MS.Apply;
    // Освободим лицензию
    Lic := Null;
End Sub UserProc;

После выполнения примера будет создана новая группа и новый пользователь. Пользователь будет включен в данную группу. Для пользователя будут розданы две привилегии: привилегия на вход в платформу и привилегия на чтение и открытие объектов. При первом входе в платформу под данным пользователем будет выдан запрос на смену пароля.

См. также:

IMetabaseSecurity